/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

plugins {
    id 'com.android.test'
}

android {
    namespace = 'org.mozilla.fenix.benchmark'

    compileSdk { version = release(config.compileSdkMajorVersion) { minorApiLevel = config.compileSdkMinorVersion } }

    defaultConfig {
        minSdk config.minSdkVersion
        targetSdk config.targetSdkVersion
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        // This benchmark buildType is used for benchmarking, and should function like your
        // release build (for example, with minification on). It's signed with a debug key
        // for easy local testing.
        benchmark {
            debuggable = true
            signingConfig = signingConfigs.debug
            matchingFallbacks = ["release"]
        }
    }

    targetProjectPath = project.findProject(":app") != null ? ":app" : ":fenix"
    experimentalProperties["android.experimental.self-instrumenting"] = true

    testOptions {
        managedDevices {
            localDevices {
                pixel6Api34 {
                    device = "Pixel 6"
                    apiLevel = 34
                    systemImageSource = "google"
                }
            }
        }
    }
}

dependencies {
    implementation libs.androidx.benchmark.macro.junit4
    implementation libs.androidx.core
    implementation libs.androidx.test.espresso.core
    implementation libs.androidx.test.junit
    implementation libs.androidx.test.uiautomator
    implementation libs.mockwebserver
    implementation project(':components:support-android-test')
}

androidComponents {
    beforeVariants(selector().all()) {
        enable = (buildType == "benchmark")
    }
}